@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
PLAYWAVEFILE
SHIRE.WAV
DONTPLAYWONDERS
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Fellowship
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Evil
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Good
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=1
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=2
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=3
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=4
talkertype=HumanOrComputer
listener=Fellowship
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
UNITKILLED
unit=Gandalf
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
Gandalf has fallen into shadow!
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Strider
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
Aragorn, son of Arathorn, has fallen. The light of the kings of old is extinguished forever.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Frodo
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
^^Frodo, the ring-bearer, is struck a mortal blow.
^^The enemy have reclaimed the One Ring!!
^
^^GAME OVER!
ENDTEXT
PLAYWAVEFILE
THEME.WAV
@ENDIF

@IF
UNITKILLED
unit=Sam
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
Samwise Gamgee, faithful hobbit to the end, is struck down. Never now will he see
his beloved Shire again. Nor get chance to speak the words to Rose that he'd never dared
^He promised to stick with Frodo to the bitter end, and indeed, bitter his end has become, dying
here so far from home.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Merry
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
Merry has been slain!
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Pippin
attacker=ANYBODY
defender=Fellowship
@THEN
TEXT
Pippin - Peregrin Took - has been slain!
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Black Rider
attacker=Fellowship
defender=Evil
@THEN
TEXT
The Black Rider is caught off guard and put to flight!
ENDTEXT
@ENDIF

@IF
TURN
turn=66
@THEN
CHANGETERRAIN
terraintype=4
maprect
131,29,131,29,131,29,131,29
@ENDIF

@IF
UNITKILLED
unit=Man
attacker=Fellowship
defender=1
@THEN
TEXT
The curious traveller is in fact a spy!
^The roads are not safe. It would be better, though slower, to travel with greater discretion.
ENDTEXT
CREATEUNIT
unit=Spy
owner=Evil
veteran=no
homecity=none
locations
19,31
20,32
19,33
endlocations
@ENDIF

@IF
UNITKILLED
unit=Old Man Willow
attacker=Fellowship
defender=Evil
@THEN
TEXT
At last, tired beyond measure, the hobbits can go no further. Beneath the boughs of a huge willow
tree they make camp, but this is no ordinairy tree. They suddenly find themselves held in a spell --
the tree is intent on killing them!
^"Help! Help!" you cry.
^And from down the path there comes a strange reply:
^
^^Hey dol! merry dol! ring a dong dillo!
^^Ring a dong! hop along! fal lal the willow!
^^Tom Bom, jolly Tom, Tom Bombadillo!
^
^A strange man dances forward and puts a stop to the mischevous willow -- saving you all. He
then dances off down the path and bids you follow.
ENDTEXT
CREATEUNIT
unit=Tom Bombadil
owner=1
veteran=no
homecity=None
locations
56,58
endlocations
PLAYWAVEFILE
CUSTOM2.WAV
@ENDIF

@IF
UNITKILLED
unit=Unknown(1)
attacker=Fellowship
defender=2
@THEN
TEXT
From the rear comes the sound of heavy hooves on the road. At first you think it might be
Gandalf, catching up with you at last. But, you are suddenly afraid and feel you should get off the
road.
ENDTEXT
CREATEUNIT
unit=Black Rider
owner=Evil
veteran=no
homecity=None
locations
13,51
14,50
12,52
endlocations
PLAYWAVEFILE
WHINNY.WAV
@ENDIF

@IF
UNITKILLED
unit=Unknown(1)
attacker=Fellowship
defender=3
@THEN
TEXT
You stop to rest for a moment. Here the trail splits; left to Stock or right to Woodhall. As you
decide which route to take, your thoughts are interupted by the sound of an approaching rider.
^A feeling of dread suddenly grips you and you think it would be for the best to avoid this
mysterious rider.
^Then, from the south you hear clear and beautiful voices, singing ancient songs in the high Elven
tongue. Whoever the rider might be, if he is an agent of the Enemy, he will surely shy from meeting
Elves.
ENDTEXT
CREATEUNIT
unit=Black Rider
owner=Evil
veteran=no
homecity=None
locations
21,49
19,51
22,50
endlocations
PLAYWAVEFILE
WHINNY.WAV
@ENDIF

@IF
UNITKILLED
unit=Elf
attacker=Fellowship
defender=1
@THEN
TEXT
To your joy and astonishment there are indeed Elven folk in the woods. You listen, spell-bound
as they complete their beautiful song:
^
^^O Elbereth! Gilthoniel!
^^We still remember, we who dwell
^^In this far land beneath the trees,
^^Thy starlight on the Western Seas.
^
^Their leader, Gildor Iglorion, a High Elf of the House of Finrod, speaks with you as you travel
further into the wood. He warns you against any contact with Black Riders, saying they are
deadly. Then he sees you are made comfortable for the night; and you sleep soundly.
^On waking you find that the Elves have all departed. And in the daylight you no longer feel as
scared as you had been.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Unknown(1)
attacker=Fellowship
defender=1
@THEN
TEXT
On the road to the Bucklebury Ferry you meet Merry. He explains that he has moved all your
belongings into your new home at Crickhollow and he is here to see you safely over the River
Brandywine.
ENDTEXT
CREATEUNIT
unit=Merry
owner=Fellowship
veteran=no
homecity=None
locations
34,50
34,54
33,51
33,53
endlocations
@ENDIF

@IF
UNITKILLED
unit=Unknown(1)
attacker=Fellowship
defender=1
@THEN
CREATEUNIT
unit=Ferry
owner=Fellowship
veteran=no
homecity=None
locations
35,51
endlocations
@ENDIF

@IF
UNITKILLED
unit=Unknown(1)
attacker=Fellowship
defender=4
@THEN
TEXT
^^A Conspiracy Unmasked!
^Arriving at last at Crickhollow you begin thinking of ways to say goodbye to Merry and Pippin,
both of whom think that you will be staying here in your new home. But, before you can say a
word, they reveal that they know all about your plan to take the Enemy's Ring to the Elves of
Rivendell: moreover, they intend to come with you.
^"We're your friends Frodo!" says Merry, "you can trust us to stick to you through thick and thin
-- to the bitter end. But you cannot trust us to let you face trouble alone, and go off without a
word!"
^At first you are angry that they knew so much when you'd let slip so little, but deep inside you
feel greatly warmed that you have such good friends.
^So, it is settled. Merry and Pippin will travel with you on your journey to Rivendell.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Tom Bombadil
attacker=Fellowship
defender=1
@THEN
TEXT
You try to keep up with the merry little chap but he is much faster. Soon you can only just hear
his voice, singing in the distance:
^
^^"Hop along, my little friends, up the Withywindle!
^^Tom's going on ahead candles for to kindle.
^^Down west sinks the Sun: soon you will be groping.
^^When the night-shadows fall, then the door will open,
^^Out of the window-panes light will twinkle yellow.
^^Fear no alder black! Heed no hoary willow!
^^Fear neither root nor bough! Tom goes on before you.
^^Hey now! Merry dol! We'll be waiting for you!"
ENDTEXT
CREATEUNIT
unit=Tom Bombadil
owner=2
veteran=no
homecity=none
locations
59,55
endlocations
PLAYWAVEFILE
CUSTOM2.WAV
@ENDIF

@IF
UNITKILLED
unit=Tom Bombadil
attacker=Fellowship
defender=2
@THEN
TEXT
Not far ahead you can see Tom Bombadil's house, and from it issues his song:
^
^^"Hey! Come derry dol! Hop along my hearties!"
^
^His song is suddenly joined by another clear singing voice, both young and as ancient as Spring;
'tis the voice of the River Daughter.
^
^Soon the hobbits will be on the threshold and the golden light will be all about them.
ENDTEXT
CREATEUNIT
unit=Tom Bombadil
owner=3
veteran=no
homecity=none
locations
63,55
endlocations
PLAYWAVEFILE
CUSTOM2.WAV
@ENDIF

@IF
UNITKILLED
unit=Tom Bombadil
attacker=Fellowship
defender=3
@THEN
TEXT
^^In the House of Tom Bombadil
^Resting in Tom's house is the safest you've felt since leaving your own happy house of Bagend.
And there you are waited upon by the River Daughter, Goldberry -- who's voice you heard
singing with Tom not long ago.
^She says of Tom, "He is the master of wood, water, and hill. He has no fear, for Tom is master."
While talking with you, Tom chuckles and takes the Enemy's ring, sliding it onto his finger. It takes
a moment for you to realise it, but amazingly, Tom doesn't disappear! Indeed, he seems to make
light of what even Gandalf thought perilous. He then gives the ring back. Startled, you put the ring
on and instantly become invisible -- to all save Tom!
^"Take off your golden ring!" he says, "Your hand's more fair without it."
^Talk gets round to where you should head next. Tom suggests the village of Bree, but to avoid
the Barrow-downs, directly east: They are a fell place, haunted by terrible Barrow-wights: ghostly
creatures that wander the downs looking for victims; so say the dread rumours that are whispered
even as far afield as the Shire. Tom says that, should you be caught by ill luck, sing this song and
he will come to your aid:
^
^^"Ho! Tom Bombadil! Tom Bombadillo!
^^By water, wood and hill, by the reed and willow,
^^By fire, sun and moon harken now and hear us!
^^Come, Tom Bombadil, For our need is near us!"
ENDTEXT
CREATEUNIT
unit=Unknown(4)
owner=1
veteran=no
homecity=none
locations
65,55
endlocations
PLAYWAVEFILE
CUSTOM2.WAV
@ENDIF

@IF
UNITKILLED
unit=Strange aura
attacker=Fellowship
defender=2
@THEN
TEXT
The barrow is the lair of an unquiet spirit: a Barrow Wight! You are captured and it seems are
assured of an icy grave, but then Tom's Rhyme wakens in your mind. Even the merest thought of
it fills you with hope and you suddenly find yourself singing:
^
^^"Ho! Tom Bombadil! Tom Bombadillo!
^^By water, wood and hill, by the reed and willow,
^^By fire, sun and moon harken now and hear us!
^^Come, Tom Bombadil, For our need is near us!"
^
^For a long moment only a deep silence comes as a reply. Then, with a great rumble, a voice as if
from far away or from underground sings:
^
^^Old Tom Bombadil is a merry old fellow,
^^Bright blue his jacket is, and his boots are yellow.
^^None has ever caught him yet, for Tom, he is the master:
^^His songs are stronger songs, and his feet are faster.
^
^Sure enough; along comes Tom and the Wight is destroyed: You are saved!
ENDTEXT
CREATEUNIT
unit=Tom Bombadil
owner=4
veteran=no
homecity=none
locations
72,32
endlocations
PLAYWAVEFILE
CUSTOM3.WAV
@ENDIF

@IF
UNITKILLED
unit=Tom Bombadil
attacker=Fellowship
defender=4
@THEN
TEXT
Tom is pleased to be of service and after opening up the Barrow-wight's lair to bright sunshine,
hands you each a sword from the dead thing's treasure horde. You marvel at the craftmanship of
the blades; all the work of an ancient people from Westernesse, an island long lost to the world
and memory.
^He then ushers you northward:
^"The road lies ahead, and Bree just beyond."
^You try to convince him to come with you but he says:
^
^"Tom's country ends here: he will not pass the borders. Tom has his house to mind, and
Goldberry is waiting!"
^
^With that he jumps upon his pony and makes his way home, singing as he goes. You can't help
but watch him until he is finally out of sight. Feeling sad at this parting, you wonder if, in years to
come, will people even remember this part of your tale
ENDTEXT
CHANGEMONEY
receiver=Fellowship
amount=100
PLAYWAVEFILE
CUSTOM2.WAV
@ENDIF

@IF
UNITKILLED
unit=Unknown(2)
attacker=Fellowship
defender=2
@THEN
TEXT
^^At the Sign of The Prancing Pony.
^At last you arrive in Bree, chief village of Bree-land. It was here that Gandalf was to meet with
you. But, after enquiring at the inn, The Prancing Pony, you discover Gandalf has not been seen in
these parts for months!
^After being relieved to get here you suddenly feel in danger again. Even though Bree is just a
village, you've never seen so many 'big-folk' before. Many of them look foul and wayward: any of
them could easily be working for the Enemy. One in particular stands out, a Ranger called Strider,
he seems to watch you with great interest.
^You try to keep a low profile while at the inn, but the other guests want to hear Shire tales and
news, and, as much as you put them off, you are coaxed foolishly into singing a Shire song.
^At first you are nervous, but such is the atmosphere in the room that you quite forget yourself,
singing and dancing, you tumble from a table and amazingly, find the ring has placed itself on your
finger! The inn is in uproar as you vanish right under everybody's noses!
^You quickly remove the ring and reappear, but are deeply chilled. While invisible you felt that
the enemy had sensed your whereabouts. Moreover, his agents were coming for you! As you try
to calm the inn's occupants your shoulder is grasped by a strong hand and you are forced into a
dark room...
^To find out what happens next, ensure all your characters are in Bree then save your game as
'Game1.sav', end the game then run 'Fell.bat', choosing '2' from the options. Next reload
'Game1.sav' and continue.
ENDTEXT
PLAYWAVEFILE
SHIRE.WAV
@ENDIF

@IF
UNITKILLED
unit=Unknown(2)
attacker=Fellowship
defender=3
@THEN
TEXT
Ahead lies the Brandywine Bridge. You wonder how safe passage over it will be:
^Surely the Enemy will have it watched night and day?
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Unknown(2)
attacker=Fellowship
defender=4
@THEN
TEXT
^^A Short Cut to Mushrooms
^Mid way across the fields you come to Farmer Maggots farm. He makes sure that the party is
rested and well fed before heading on: all are treated to bacon, mushrooms and plenty of beer!
^Prior to leaving, Maggot tells you that a strange rider in black had called only moments earlier, "a
proper rum fellow," says Maggot, "I didn't like the look of him. He asked about travelling hobbits
and one by the name of Baggins. Well, I sent him on his way, but he said he'd be back -- with
gold too!"
^The farmer calms you and assures you that you are safe, if the rider does come back, Maggot
wont give you away.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Unknown(3)
attacker=Fellowship
defender=1
@THEN
TEXT
^^The Old Forest
Passing beneath the eaves of the Old Forest you begin to wonder if this route will be the short cut
you'd hoped it would. For the trees quickly seem to grow thicker and thicker all about you,
constantly slowing your progress. It's a mysterious place too, full of dark, long abandoned
corners. It may not be safe to travel on the roads -- but, will it be any safer in here?
^You have the uncomfortable feeling of being watched with disapproval, deeping to dislike and
even emnity. This grows to the point where, as you travel, you find yourself constantly looking
over your shoulder, as if expecting a sudden blow.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Unknown(3)
attacker=Fellowship
defender=3
@THEN
TEXT
You feel sure that you will never escape this terrible forest. It seems to drain you of all energy and
hope.
^As the relentless sun stiffles all the air beneath the forest's dark branches you feel foolish for ever
having taken the path through here.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Strange Aura
attacker=Fellowship
defender=Evil
@THEN
TEXT
You discover gold and treasure in the ancient Barrow!
ENDTEXT
CHANGEMONEY
receiver=Fellowship
amount=50
@ENDIF

@IF
UNITKILLED
unit=Unknown(3)
attacker=Fellowship
defender=4
@THEN
TEXT
^^The Shadow of the Past.
^After discovering that his Uncle Bilbo's magic ring is in fact the One Ring -- cut from the hand of
Sauron himself -- and that the Great Enemy is even now searching for it, Frodo realises that he
must leave the Shire so that it will be kept safe from danger.
^Gandalf has advised him to take the Ring to the Elves of Rivendell. It should be safe there and
hidden from all eyes. For if the Enemy should ever reclaim his Ring, he will use it's power to
plunge the world into eternal shadow.
^
^Frodo is upset at having to leave his beloved Bagend but needs must. Gandalf should have been
here to travel with him, but there's been no word from him in quite some time. Now, Frodo can
wait no longer: he and his travel companions, Sam and Pippin, must set out before it's too late.
^So as the sun sets on Bagend, Frodo waves it goodbye, possibly never to see it again; Pippin
hoists his pack onto his back; and Sam wipes foam from his mouth after a tearful farewell to
Frodo's beer-barrel.
ENDTEXT
CREATEUNIT
unit=Sam
owner=Fellowship
veteran=no
homecity=Bag End
locations
3,15
4,16
endlocations
@ENDIF

@IF
UNITKILLED
unit=Unknown(3)
attacker=Fellowship
defender=4
@THEN
CREATEUNIT
unit=Pippin
owner=Fellowship
veteran=no
homecity=none
locations
3,15
4,16
endlocations
@ENDIF

@IF
UNITKILLED
unit=Man
attacker=Fellowship
defender=2
@THEN
TEXT
On the road to Scary you are met by a tall man with a bow, wearing a silver-star clasped cloak..
^He approaches you and tells you that these roads are not safe for travelling gentle-hobbits; there
is much evil about.
^He introduces himself as Halbaradin; and says that as a Ranger of the North, it is his duty to
offer you his protection.
ENDTEXT
CREATEUNIT
unit=Ranger
owner=Fellowship
veteran=yes
homecity=none
locations
11,13
12,14
13,13
endlocations
@ENDIF

@IF
UNITKILLED
unit=Unknown(4)
attacker=Fellowship
defender=1
@THEN
TEXT
^^Fog on the Barrow-downs
^After resting for a time in Tom Bombadil's house you decide to continue your journey; but
staying ever mindful of Tom's warning of the wight's and ghouls that prowl about the
Barrow-downs.
^To the north you spy the road that leads to Bree. You know that the best route from here would
be one that took you to the road as swiftly as possible, but in the near distance you also see that a
fog is rising and your journey may not be as straight forward an affair as you'd like.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Strange Aura
attacker=Fellowship
defender=1
@THEN
TEXT
In the deeps of the forest you discover an old burial mound.
^Inside, you discover a horde of golden treasure!
ENDTEXT
CHANGEMONEY
receiver=Fellowship
amount=100
@ENDIF

@IF
UNITKILLED
unit=Halfling
attacker=Fellowship
defender=1
@THEN
TEXT
As you pass through the sleepy village of Bywater, several hobbits wave you on your way.
^No doubt they'll tell other hobbits, who'll tell others and before long, should you stay on the
road, rumours of your travel plans will surely come to the enemy's ears!
ENDTEXT
CREATEUNIT
unit=Spy
owner=Evil
veteran=no
homecity=none
locations
10,34
9,35
11,33
11,31
endlocations
@ENDIF

@IF
UNITKILLED
unit=Unknown(4)
attacker=Fellowship
defender=2
@THEN
TEXT
You feel sure that you spied, albeit briefly, a cloaked figure with a bow, watching you from the
woods.
^You feel aprehensive and wonder if this route is safe.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Hobbit
attacker=Fellowship
defender=2
@THEN
TEXT
You find a lost hobbit called Rabon Gumm. He says that he's been wandering around for what
seems like days. He thought he'd take a short cut through the Old Forest to get to his new job in
Bree. He tells you that he was supposed to take a job at the Prancing Pony, baking loaves. Now,
most likely he'll have lost his job before he's even started it!
^You scratch your head but point the way back to Crickhollow. He thanks you and bids you a
good journey.
ENDTEXT
CREATEUNIT
unit=Halfling
owner=2
veteran=no
homecity=none
locations
76,20
endlocations
@ENDIF

@IF
UNITKILLED
unit=Tom Bombadil
attacker=Fellowship
defender=4
@THEN
CHANGETERRAIN
terraintype=1
maprect
68,28,68,28,68,28,68,28
@ENDIF

@IF
RANDOMTURN
denominator=4
@THEN
PLAYWAVEFILE
BIRDSNG1.WAV
@ENDIF

@IF
RANDOMTURN
denominator=2
@THEN
PLAYWAVEFILE
BIRDSNG2.WAV
@ENDIF

@IF
RANDOMTURN
denominator=5
@THEN
PLAYWAVEFILE
BIRDSNG8.WAV
@ENDIF

@IF
RANDOMTURN
denominator=3
@THEN
PLAYWAVEFILE
BIRDSNG3.WAV
@ENDIF

@ENDEVENTS
